1С 8.3 Подбор из справочника в табличную часть
Не устроил ответ?
Зарегистрируйся и задай свой вопрос. Живое общение приносит результат намного быстрее.
Реклама
Новые вакансии
- Вакансия «Прораммист/разработчи 1С» Екатеринбург от Денис Спеиалист
Вчера в 13:10 - Вакансия Стажер Аналитик от Elizavetashkr
17 ноября 2023 г. - Вакансия Стажер Программист 1С от Elizavetashkr
17 ноября 2023 г.
Организация подборов в табличную часть документа
Для иллюстрации механизма подбора информации в форме будем использовать задачу подбора элементов справочника Номенклатура в табличную часть документа ПриходнаяНакладная как наиболее распространенную. Поскольку механизм подбора реализован на уровне форм, то в других случаях просто будут задействованы иные прикладные объекты. Сама механика подбора не изменится.
Для организации подбора в форму документа следует открыть форму справочника как подчиненную форме документа в целом либо одному из элементов формы. Способ получения формы справочника может быть любым, также как и сама форма справочника, которая будет использована. Важно лишь то, что эта форма должна быть открыта как подчиненная.
Результат подбора будет доступен в обработчике события ОбработкаВыбора формы документа или элемента формы (в зависимости от того, чему мы подчиним форму справочника при открытии). Событие ОбработкаВыбора в форме документа будет вызвано в двух случаях:
- когда в форме справочника будет выполнен интерактивный выбор;
- когда в форме справочника будет вызван метод ОповеститьОВыборе .
Одиночный подбор
При одиночном подборе форма справочника будет закрываться сразу после выбора элемента. Для выбора следующего элемента необходимо будет снова инициировать подбор.
Откроем форму документа ПриходнаяНакладная , создадим команду Подбор и назначим для нее обработчик:
&НаКлиенте Процедура ВыборОдногоЭлемента(Команда) // Форма выбора закрывается после двойного клика // по выбранному элементу ОткрытьФорму("Справочник.Номенклатура.ФормаВыбора",,Элементы.Материалы); КонецПроцедуры
В этой процедуре мы открываем форму выбора для справочника Номенклатура , указывая, что она подчинена таблице Материалы формы документа ПриходнаяНакладная ( Элементы.Материалы ). При выборе из формы выбора справочника выбранное значение будет передано в обработчик события ОбработкаВыбора таблицы формы Материалы , так как она является владельцем открытой формы выбора.
Поэтому откроем палитру свойств таблицы Материалы и создадим обработчик события ОбработкаВыбора :
&НаКлиенте Процедура МатериалыОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка) Элементы.Материалы.ДобавитьСтроку(); Элементы.Материалы.ТекущиеДанные.Материал = ВыбранноеЗначение; КонецПроцедуры
В этой процедуре мы добавляем новую строку в таблицу Материалы и присваиваем колонке Материал в новой строке выбранное в форме выбора справочника значение. Это значение передается в обработчик события в параметре ВыбранноеЗначение .
Множественный подбор
При множественном подборе форма справочника будет открыта до тех пор, пока пользователь не закроет ее интерактивно или не будет вызван метод формы Закрыть() .
Обработчик команды Подбор :
&НаКлиенте Процедура ВыборЭлементовБезЗакрытияФормы(Команда) // Не закрывать форму после двойного клика; можно выбрать // несколько элементов, дважды кликая на каждом ПараметрыФормы = Новый Структура("ЗакрыватьПриВыборе", Ложь); ОткрытьФорму( "Справочник.Номенклатура.ФормаВыбора", ПараметрыФормы, Элементы.Материалы ); КонецПроцедуры
Обработчик события ОбработкаВыбора остается без изменений.
Подбор с использованием множественного выбора
Еще одним способом организации подбора является возможность выделения в списке сразу нескольких строк. Режим множественного выделения в списке устанавливается, как правило, во всех формах списков по умолчанию. Однако возможность выбрать сразу несколько элементов из списка по умолчанию, как правило, отключена.
Поэтому для того, чтобы в форме списка справочника Номенклатура можно было не только отметить, но и выбрать сразу несколько элементов, мы воспользуемся одним из параметров расширения формы динамического списка — МножественныйВыбор .
Обработчик команды Подбор :
&НаКлиенте Процедура МножественныйВыбор(Команда) // Позволяем выделить и выбрать несколько элементов; в обработчик // ОбработкаВыбора() передается массив элементов ПараметрыФормы = Новый Структура("МножественныйВыбор", Истина); ОткрытьФорму( "Справочник.Номенклатура.ФормаВыбора", ПараметрыФормы, Элементы.Материалы ); КонецПроцедуры
Обработчик события ОбработкаВыбора :
&НаКлиенте Процедура МатериалыОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка) Для Каждого ВыбранныйЭлемент Из ВыбранноеЗначение Цикл НоваяСтрока = Объект.Материалы.Добавить(); НоваяСтрока.Материал = ВыбранныйЭлемент; КонецЦикла; КонецПроцедуры
Множественный подбор с использованием множественного выбора
Последний способ подбора сочетает в себе оба рассмотренных ранее способа. Мы будем отмечать сразу несколько элементов справочника и подбирать их в документ без закрытия формы выбора. Затем снова отмечать несколько элементов справочника и подбирать их в документ. Для этого нам будет необходимо при открытии формы выбора установить оба параметра: ЗакрыватьПриВыборе и МножественныйВыбор .
Обработчик команды Подбор :
&НаКлиенте Процедура МножественныйВыборБезЗакрытияФормы(Команда) // Позволяем выделить и выбрать несколько элементов несколько раз; в // обработчик ОбработкаВыбора() передается массив элементов; после // каждого выбора форма не закрывается ПараметрыФормы = Новый Структура( "ЗакрыватьПриВыборе,МножественныйВыбор", Ложь, Истина ); ОткрытьФорму( "Справочник.Номенклатура.ФормаВыбора", ПараметрыФормы, Элементы.Материалы ); КонецПроцедуры
Обработчик события ОбработкаВыбора остается без изменений.
Использование метода ОповеститьОВыборе()
Метод формы ОповеститьОВыборе() используется в тех случаях, когда алгоритм формирования данных подбора сложен и кроме собственно выбора элемента справочника от пользователя требуется указание некоторой дополнительной информации. В этом случае метод ОповеститьОВыборе() вызывается тогда, когда вся необходимая информация подбора сформирована.
Метод ОповеститьОВыборе() посылает оповещение владельцу формы о выполнении выбора или подбора, передает ему выбранное значение и закрывает форму, если она открыта не в режиме множественного выбора.
Также метод ОповеститьОВыборе() может использоваться в тех случаях, когда требуется передать в форму документа не только выбранный элемент справочника (или массив элементов), а некоторую произвольную структуру данных.
Справка
ТабличноеПоле.ДобавитьСтроку()
ТабличноеПоле.ДобавитьСтроку()
Добавляет строку в табличное поле, аналогично выполнению команды «Добавить».
- Если табличное поле связано с таблицей или деревом значений, метод добавляет строку в таблицу или дерево значений (аналогично соответствующим методам этих объектов).
- Если табличное поле связано со списком объектов, хранимых в базе данных, метод начинает редактирование нового объекта этого списка. (Например, список объектов в форме списка справочника, или документа).
- Если табличное поле связано с набором записей или табличной частью, то метод начинает редактирование новой записи. (Например, список записей в форме списка регистра сведений; табличная часть документа или справочника).
Доступность: Толстый клиент.
ДанныеФормыКоллекция.Добавить()
ДанныеФормыКоллекция.Добавить()
Добавляет элемент в конец коллекции и возвращает его в качестве результата метода. Возвращаемое значение: ДанныеФормыЭлементКоллекции .
Доступность: тонкий клиент, веб-клиент, сервер, толстый клиент, мобильное приложение(клиент), мобильное приложение(сервер).
- Как обработать выбор значения в поле ввода
- Передача данных между управляемыми формами
- Можно ли использовать форму списка в качестве формы выбора?
- Форма динамического списка с произвольным запросом
- Как открыть форму списка с некоторым отбором?
- Параметры формы
- Связи параметров выбора
Каталог оборудования
Lorem ipsum dolor sit amet, consectetur adipiscing elit, sed do eiusmod tempor incididunt ut labore et dolore magna aliqua.
Производители
Lorem ipsum dolor sit amet, consectetur adipiscing elit, sed do eiusmod tempor incididunt ut labore et dolore magna aliqua.
Функциональные группы
Lorem ipsum dolor sit amet, consectetur adipiscing elit, sed do eiusmod tempor incididunt ut labore et dolore magna aliqua.
Категории блога
Облако тегов
- 1С:Предприятие (31)
- API (29)
- Bash (43)
- CLI (122)
- CMS (139)
- CSS (50)
- Frontend (75)
- HTML (66)
- JavaScript (150)
- Laravel (72)
- Linux (169)
- MySQL (76)
- PHP (125)
- React.js (66)
- SSH (27)
- Ubuntu (69)
- Web-разработка (509)
- WordPress (73)
- Yii2 (69)
- БазаДанных (95)
- Битрикс (66)
- Блог (29)
- Верстка (43)
- ИнтернетМагаз… (84)
- КаталогТоваров (87)
- Класс (30)
- Клиент (28)
- Ключ (28)
- Команда (87)
- Компонент (60)
- Конфигурация (64)
- Корзина (32)
- ЛокальнаяСеть (32)
- Модуль (34)
- Навигация (31)
- Настройка (141)
- ПанельУправле… (29)
- Плагин (33)
- Пользователь (26)
- Практика (101)
- Сервер (75)
- Событие (27)
- Теория (106)
- Установка (66)
- Файл (51)
- Форма (58)
- Фреймворк (192)
- Функция (36)
- ШаблонСайта (68)
Подбор из справочника на основе управляемых форм
В данной статье рассматривается технология реализации подбора на платформе 1С 8.2. Статья не претендует на академизм, просто столкнувшись с рядом проблем и не нашедшим «правильной» методологии решения (возможно плохо искал), решил пройти этот путь самостоятельно, естественно пользуясь различными источниками. В основном я опираюсь на материалы мастер-групп Базового курса «Профессиональное программирование в 1С» Евгения Гилева и Насипова Фарита, участником которого я являюсь, а также соответствующей литературы (М.Г. Радченко, Е.Ю. Хрусталева Практическое пособие разработчика).
Итак, предметная область: компания занимается оптовой торговлей товарами имеющими срок годности, который относится к серии, а та в свою очередь принадлежит конкретному товару. Товары поступают на разные склады. Задача: реализовать удобное заполнение табличной части расходного документа. Решение: необходимо реализовать форму подбора, обеспечивающею просмотр остатков товара по срокам годности, возможность выбора соответствующих позиций и последующий перенос в табличную часть документа. Задачи такого плана встречаются в 5 части сборника задач к подготовке экзамена по Специалисту.
Реализация. Создаем форму произвольного типа для документа Продажа товаров. Можно конечно создать общую форму, но в данной ситуации выбираем то, что поближе. На форме создаем реквизиты:
Склад — тип СправочникиСсылка.Склады
Товары — Динамический список, в свойствах ставим галочку произвольный запрос.
Выбор — таблица значений (колонки Товар, Серия — тип ссылки на соответствующие справочники, срок годности, количество — дата, число).
Настраиваем запрос для реквизита Товары. Здесь по идее все просто с помощью конструктора берем два справочника и виртуальную таблицу Остатков регистра Остатки товара. Если нужно видеть весь товар, то используем левое соединение Товаров с остальными источниками, если только с остатками, то полное соединение с регистром:
Код 1C v 8.2 УП
ВЫБРАТЬ
Товары.Ссылка КАК Товар,
Серии.Ссылка КАК Серия,
Серии.СрокГодности,
ЕСТЬNULL(ТоварыНаСкладеОстатки.КоличествоОстаток, 0) КАК Количество
ИЗ
Справочник.Товары КАК Товары
ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Серии КАК Серии
ПО (Серии.Владелец.Ссылка = Товары.Ссылка)
ПОЛНОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладе.Остатки(, Склад = &Склад) КАК ТоварыНаСкладеОстатки
ПО (ТоварыНаСкладеОстатки.Товар = Товары.Ссылка)
УПОРЯДОЧИТЬ ПО
Товар,
СрокГодности
Для виртуальной таблицы в параметрах указываем отбор по складу. После этого я 3 часа топтался на одном месте. Когда я запустил данную форму в процессе отладки, то я увидел только одну строчку с товаром, хотя их должно было быть больше. Честно говоря и растерялся, так как по идее все должно быть просто но . И вот около 3 часов я пытался понять почему не выводятся все записи. Конечно, может это и не является серьезной проблемой и большинство практикующих специалистов 1С про нее знают, но только после долгого серфинга по Интернету я нашел, что надо очистить свойство основная таблица в окне настройки запроса динамического списка, и тогда появились все записи. При этом становится неактивным свойство динамическое считывание данных. В книге «Разработка управляемого интерфейса» мне не удалось найти назначение параметра основная таблица и описание это ситуации. Сразу хочу отметить, что в типовой конфигурации управление небольшой фирмой используется не динамический список, а дерево значений.
И так, возвращаемся в нормальное русло решение задачи.
В разработанной форме я добавил параметр Склад с целью отбора остатков.
Для того чтобы открыть созданную форму подбора, в управляемой форме документы Продажа товара создаем команду подбор, размещаем на форме о генерируем обработчик, в котором нам необходимо открыть форму. Так как форма должна обеспечивать множественный выбор и отбор по складу, то создаем структуру параметров формы. И открываем форму соответствующей командой.
Код 1C v 8.2 УП
&НаКлиенте
Процедура Подбор(Команда)
ПараметрыПодбора = Новый Структура("ЗакрыватьПриВыборе, МножественныйВыбор, Склад", Ложь, Истина, Объект.Склад);
ОткрытьФорму("Документ.ПродажаТоваров.Форма.ФормаПодбора", ПараметрыПодбора, Элементы.Товары);
КонецПроцедуры
Соответственно в форме подбора при создании заполняем параметр запроса склад из параметров формы:
Код 1C v 8.2 УП
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
Товары.Параметры.УстановитьЗначениеПараметра("Склад",Параметры.Склад);
Склад = Параметры.Склад;
КонецПроцедуры
Теперь необходимо реализовать функционал формы подбора. При выборе соответствующей строки она должна переносится в таблицу значений, так же должен работать механизм перетаскивания. Для решения первой задачи необходимо создать обработчик события Выбор нашего динамического списка.
Код 1C v 8.2 УП
&НаКлиенте
Процедура ТоварыВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
Для каждого НомерСтроки Из ВыбраннаяСтрока Цикл
ТекСтрока = Элемент.ДанныеСтроки(НомерСтроки);
Поиск = Новый Структура("Товар, Серия",ТекСтрока.Товар,ТекСтрока.Серия);
МассивСтрок = ВыбранныеТовары.НайтиСтроки(Поиск);
Если МассивСтрок.Количество() = 0 Тогда
Строка = ВыбранныеТовары.Добавить();
Строка.Товар = ТекСтрока.Товар;
Строка.Серия = ТекСтрока.Серия;
Строка.СрокГодности = ТекСтрока.СрокГодности;
Строка.Количество = 1;
ВвестиЧисло(Строка.Количество, "Введите количество");
Пока Строка.Количество > ТекСтрока.Количество Цикл
ВвестиЧисло(Строка.Количество, "Введите верное количество!");
КонецЦикла;
КонецЕсли;
КонецЦикла;
КонецПроцедуры
В нем имеется параметр ВыбраннаяСтрока представляющий собой массив, элементами которого являются номера строк списка Товары. В цикле проверяем не дублируются ли выбранные строки и запрашивается количество.
Для реализации перетаскивания необходимо проверить настройку следующих параметров: Для таблицы Товары — РазрешитьНачалоПеретаскивания, для Выбранные товары — РазрешитьПеретаскивание.
Так же необходимо создать обработчик события Перетаскивание для элемента формы ВыбранныеТовары.
Код 1C v 8.2 УП
&НаКлиенте
Процедура ВыбранныеТоварыПеретаскивание(Элемент, ПараметрыПеретаскивания, СтандартнаяОбработка, Строка, Поле)
Для каждого НомерСтроки Из ПараметрыПеретаскивания.Значение Цикл
ТекСтрока = Элементы.Товары.ДанныеСтроки(НомерСтроки);
Поиск = Новый Структура("Товар, Серия",ТекСтрока.Товар,ТекСтрока.Серия);
МассивСтрок = ВыбранныеТовары.НайтиСтроки(Поиск);
Если МассивСтрок.Количество() = 0 Тогда
Строка = ВыбранныеТовары.Добавить();
Строка.Товар = ТекСтрока.Товар;
Строка.Серия = ТекСтрока.Серия;
Строка.СрокГодности = ТекСтрока.СрокГодности;
Строка.Количество = 1;
ВвестиЧисло(Строка.Количество, "Введите количество");
Пока Строка.Количество > ТекСтрока.Количество Цикл
ВвестиЧисло(Строка.Количество, "Введите верное количество!");
КонецЦикла;
КонецЕсли;
КонецЦикла;
КонецПроцедуры
Так как код обработчика похож на предыдущий, то для оптимизации можно создать процедуры и вызывать ее из обоих обработчиков.
На рисунке приведен внешний вид формы подбора:
Для завершения подбора создана команда формы, с обработчиком, выполняющим оповещение о выборе:
Код 1C v 8.2 УП
&НаКлиенте
Процедура Перенести(Команда)
ОповеститьОВыборе(ВыбранныеТовары);
Закрыть();
КонецПроцедуры
Соответственно, в форме документа реализован обработчик события ОбработкаВыбора:
Код 1C v 8.2 УП
&НаКлиенте
Процедура ТоварыОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)
Если ВыбранноеЗначение.Количество() > 0 И Объект.Товары.Количество() > 0 Тогда
Режим = РежимДиалогаВопрос.ДаНет;
Текст = "Очистить табличную часть?";
Ответ = Вопрос(Текст, Режим, 0);
Если Ответ = КодВозвратаДиалога.Да Тогда
Объект.Товары.Очистить();
КонецЕсли;
КонецЕсли;
Для каждого Подбор Из ВыбранноеЗначение Цикл
Строка = Объект.Товары.Добавить();
Строка.Товар = Подбор.Товар;
Строка.Серия = Подбор.Серия;
Строка.Количество = Подбор.Количество;
КонецЦикла;
КонецПроцедуры
Кроме того, есть еще несколько тюнинговых настороек, про которые писать особого смысла нет, но для формы подбора желательно не забыть настроить свойство РежимОткрытияОкна — Блокировать окно владельца, чтобы пользователь не смого ее случайно вернутся в документ не закрыв окно подбора, при этом доступ к основному окну будет.
В целом хочется еще раз подчеркнуть, что целью данной статьи не является проповедование истины, а просто поделится полученной информацией. Буду благодарен за конструктивные советы и рекомендации, так как тема управляемых форм достаточно новая, но похоже надолго, и ряд вопросов (особенности работы с произвольными запросами) требует дополнительной информации.
Автор: User67
1с как сделать подбор из справочника
Подскажите, как программно реализовать подбор из справочника по кнопке подбор. Создан свой справочник, необходимо, чтоб по кнопке подбор, открывалась форма выбора номенклатуры и можно было выбирать несколько номенклатур и они автоматически переносятся в созданный справочник.
(0) Просто интересно, каким образом ты видишь «подсказку»?
Написать процедуру подбора и выложить?
(1) было бы неплохо конечно))) но может вы подскажите примерный алгоритм
Подбор из справочника «Номенклатура» в документы реализован в типовых конфигурациях, например, в УТ 10.3. Нужно посмотреть, как это реализовано и сделать по аналогии. В вашем справочнике надо написать процедуры обработки подбора, чтобы выбранные значения куда-то попадали.
Первое правило подбора — не смотри в код типовых конфигураций.
Второе правило подбора — НИКОГДА не смотри в код типовых конфигураций.
Третье правило подбора — не думай, а сразу иди на форум и проси готовое решение.
(3)начала делать вот так
Спр=Справочники.Номенклатура;
ФормаВыб=Спр.ПолучитьФормуВыбора(«ФормаВыбора»,ЭтаФорма);
ФормаВыб.РежимВыбора = Истина;
ФормаВыб.ЗакрыватьПриВыборе=Ложь;
ФормаВыб.МножественныйВыбор=Истина;
ФормаВыб.Открыть();
а как мне дальше получить выбранные значения не знаю
(2)
Процедура Подбор()
ФормаПодбора=Справочники[ИдентификаторТвоегоСуперСправочника].ПолучитьФормуВыбора(, ЭтаФорма);
ФормаПодбора.ЗакрыватьПриВыборе=Ложь;
ФормаПодбора.Открыть();
КонецПроцедуры
(5) А дальше лови значения в
Процедура ОбработкаВыбора(ЗначениеВыбора, Источник)
(5) Вот МножественныйВыбор тут совершенно излишен.
А в форме есть ещё обработчики событий. Типа ОбработкаВыбора, например.
(7) (8) это уже в форме номенклатуры? как мне отловить то значение? как перейти в эту процедуру? или ее нужно добавить в модуль формы списка справочника из которого делается отбор?
(9) Это в твоем справочнике из которого ты подбор вызываешь
У формы (из который ты вызываешь подбор) — есть события такие как «ПриОткрытии», «передОткрытие» и т.д. — одно из таких событий «ОбработкаВыбора»
(10) но тогда я смогу выбрать только одно значение. а мне нужно несколько
(12) прежде чем, что то спросить — сначала попробуй 🙂
(13) Процедура ДействияФормыПодбор(Кнопка)
Спр=Справочники.Номенклатура;
ФормаВыб=Спр.ПолучитьФормуВыбора(«ФормаВыбора»,ЭтаФорма);
ФормаВыб.РежимВыбора = Истина;
ФормаВыб.ЗакрыватьПриВыборе=Ложь;
ФормаВыб.МножественныйВыбор=Истина;
ВыбраннаяНоменклатура=ФормаВыб.ОткрытьМодально();
ОбработкаВыбора(ВыбраннаяНоменклатура,ФормаВыб);
Процедура ОбработкаВыбора(ЗначениеВыбора, Источник)
Ном=Справочники.СтруктураПрайсЛиста.СоздатьЭлемент();
Ном.Номенклатура=ЗначениеВыбора;
Ном.Записать();
КонецПроцедуры
(13) не получается выбрать несколько((
(15) что значит не получается? и что значит несколько?!
Сколько раз нажмешь мышкой «Выбрать» — столько раз и выберется. Либо выдели несколько позиций (благо ты поставила множественныйвыбор=истина) и «ЗначениеВыбора» придет массив
(16) я нажимаю на одну позицию, нажимаю выбрать, закрываю справочник, но в ЗначениеВыбора у меня Неопределено